model{
  for(i in 1:N){
    logw[i]~dnorm(mu[i],tausq)
    mu[i]<-(gamma[1] + beta[1,year[i]]) + 
           (gamma[2] + beta[2,year[i]]) * (age[i] - age.bar) +
           (gamma[3] + beta[3,year[i]]) * (gender[i] - gender.bar) +
           (gamma[4] + beta[4,year[i]]) * (educ[i] - educ.bar) +
           theta[subj[i]]
    }

  for(i in 1:nsubj) {theta[i]~dnorm(0,tau.theta)}
for(i in 1:nyr) { beta[1,i]~dnorm(0,tau.beta1[i])}
  
  for(i in 1:4){
    gamma[i]~dflat()
  }

  for(j in 2:4) {
    beta[j,1:nyr]~car.normal(adj[],weights[],num[],tau.beta)
  }

  weights[1]<-1;   adj[1]<-2;   num[1]<-1;
  for(t in 2:(nyr-1)){
    weights[2+(t-2)*2]<-1;   adj[2+(t-2)*2] <- t-1;  num[t]<-2
    weights[3+(t-2)*2]<-1;   adj[3+(t-2)*2] <- t+1;
  }
  weights[2+(nyr-2)*2]<-1;   adj[2+(nyr-2)*2]<-nyr-1;   num[nyr]<-1

  tausq~dgamma(0.01, 0.01)
  tau.beta~dgamma(0.01,0.01)
  tau.theta~dgamma(.01,.01)

 tau.beta1[1]~dgamma(19.53, 3.125)
  tau.beta1[2]~dgamma(19.09, 3.09)
  tau.beta1[3]~dgamma(17.05, 2.95)
  tau.beta1[4]~dgamma(16.41, 2.865)
  tau.beta1[5]~dgamma(15.73, 2.805)
  tau.beta1[6]~dgamma(15.34, 2.77)

  for(i in 1:nyr){
    b[1,i]<-gamma[1]+beta[1,i]
    b[2,i]<-gamma[2]+beta[2,i]
    b[3,i]<-gamma[3]+beta[3,i]
    b[4,i]<-gamma[4]+beta[4,i]
  }

}



data
  list(N=16654,nsubj=7284,nyr=6,
       age.bar=26.80,educ.bar=13.20,gender.bar=0.146)

inits
  list(gamma=c(0,0,0,0),
       beta=structure(
          .Data=c(1,1,1,1,1,1,
                  .01,.01, .01,.01, .01,.01,
                   -.4, -.4,-.38,-.3,-.34,-.29,
                   .07, .07, .09,.09, .11,.11),
          .Dim=c(4,6)),
       tausq=1,tau.beta=1,tau.theta=1,tau.beta1=c(1,1,1,1,1,1))

  list(gamma=c(1,1,1,1),
       beta=structure(
          .Data=c(1,1,1,1,1,1,
                  1,1,1,1,1,1,
                  1,1,1,1,1,1,
                  1,1,1,1,1,1),
          .Dim=c(4,6)),
       tausq=.1,tau.beta=.1,tau.theta=.1,tau.beta1=c(.1,.1,.1,.1,.1,.1))

  list(gamma=c(-1,-1,-1,-1),
       beta=structure(
          .Data=c(-1,-1,-1,-1,-1,-1,
                  -1,-1,-1,-1,-1,-1,
                  -1,-1,-1,-1,-1,-1,
                  -1,-1,-1,-1,-1,-1),
          .Dim=c(4,6)),
       tausq=3,tau.beta=3,tau.theta=3,tau.beta1=c(3,3,3,3,3,3))